/* sculpt.pov - oil-pastel cone, sphere, cylinder
created 31oct(tu)95
THIS FORM used for sculpt0.tga, which is printout.
readonly

 (c) Sep 1996 Jeremy Monin
 jdmonin@mailbox.syr.edu	http://web.syr.edu/~jdmonin

You can experiment and use snippets of this code; just don't rip me off.
	Details at http://web.syr.edu/~jdmonin/disclaim.htm

Missing an .inc file?
	Check out http://web.syr.edu/~jdmonin/pov/inc.htm
*/

global_settings { adc_bailout 1.3/127 }
// #max_trace_level 3

#declare blackLacquer = texture {
	pigment { color rgbf <.01, .01, .01, 0> }
	finish { phong 1	phong_size 5
		specular .2	roughness 80
		ambient 0	diffuse .1
		reflection .4	crand .003 }
}

#declare glossyBlack = texture {
	pigment { color rgbf <.01, .01, .01, 0> }
	finish { specular .3	roughness 80
		ambient 0	diffuse .1	crand .003 }
}

camera {
	location <-.5, 1, -2>
	look_at <2, .7, 2>
}

light_source { <-20, 5, 5> color rgb <1,1,1>
	spotlight
	point_at <1, 0, 1>
	radius 5 falloff 23
	area_light -4*z, 3*y, 4, 4
	adaptive 1	jitter
}
light_source { <-5, 20, 1.2> color rgb <.4,.4,.4>
	spotlight
	point_at <1, 0, 1>
	radius 8 falloff 10 // tightness 10
}

// platform for cone.
box { <0,0,0>, <1,.04,1> texture {glossyBlack} }
cone { <.5, .04, .5>, .45 <.5, 1.8, .5>, 0 texture {blackLacquer} }

sphere { <2.9, .9, .9>, .9 texture {blackLacquer} }

cylinder { <-.2, .7, 1.8>, <7.3, .7, 1.8>, .7 texture {blackLacquer} }

plane { y,0 texture {glossyBlack finish{specular .2 diffuse .03 ambient .03 } } }